Baanboard.com

Go Back   Baanboard.com > Forum > Baan SIGs > Code & Utilities

User login

Frontpage Sponsor

Main

Poll
For ERP LN feature pack upgrade, what method of install are you using?
Installation Wizard into existing VRC
35%
Installation Wizard into new VRC
42%
Manual into existing VRC
3%
Manual into new VRC
19%
Total votes: 31

Baanboard at LinkedIn


Reference Content

Reply
 
Thread Tools Display Modes
  #31  
Old 14th April 2008, 16:40
pconde pconde is offline
Senior Member
 
Join Date: May 2002
Location: Belgium
Posts: 162
pconde is on a distinguished road
Baan: BaanIVc4, BaanERP 5.0, ERP LN6.1 - DB: Oracle, informix, DB400 - OS: unix, As400, windows 2003
Hi,

In the script use option libraries to maintain the libraries that the compilation process must use

Regards
Philippe
Reply With Quote
  #32  
Old 15th April 2008, 13:43
bdittmar's Avatar
bdittmar bdittmar is offline
Guru
 
Join Date: Apr 2002
Location: Germany, 50.584097,8.544078
Posts: 1,639
bdittmar will become famous soon enough
Baan: 2.2/3.1/4c4/LN6.1 FP6/FP9/HiDox - DB: tbase, ms-sql7, oracle10gV1, 11g - OS: HP-UX, W2K3, SLES
It's standard

Quote:
Originally Posted by Fridolin View Post
Hello,

I’m just checking out the example of the tree object provided by pconde.

As compilation I receive always the error message indicating that the librairies “tggbfsrvlib” and “tgcomlogging” are not found.

I suggest that this librairies are not on my Baan IVc system!

What have I to do to install this livrairies on my system?

Regards

Fridolin
Hello Fridolin,

tggbfsrvlib and tgcomlogging are standard libs from 1998, so i can not understand that these libs are not on your system ?

Have a look at my attachment.

Regards
Attached Images
File Type: jpg tgcomlogging.jpg (59.1 KB, 76 views)
File Type: jpg tggbfsrvlib.jpg (60.4 KB, 50 views)
__________________
//Bernd
Reply With Quote
  #33  
Old 28th May 2008, 15:04
moianix's Avatar
moianix moianix is offline
Junior Member
 
Join Date: Apr 2005
Posts: 19
moianix is on a distinguished road
Baan: IV c4 - DB: Oracle - OS: Aix - Win 2003
Add menu with gbf

Hi to all.

i want to add other menu with functions ( i.e. run a baan prgram )
in a GBF screen ( Baan IV c4 ).
How can i do it ?

Thx
Reply With Quote
  #34  
Old 29th May 2008, 11:28
pconde pconde is offline
Senior Member
 
Join Date: May 2002
Location: Belgium
Posts: 162
pconde is on a distinguished road
Baan: BaanIVc4, BaanERP 5.0, ERP LN6.1 - DB: Oracle, informix, DB400 - OS: unix, As400, windows 2003
Hi here an example with function linked to menu
See code marked PCE 2 and variable hwnd.func

Code:
|******************************************************************************
|* spbom0719  0  VRC B40O c4 expl
|* Impression graphique Nomenclatures spécifiques
|* Philippe Condé                
|* 2004-08-16
|
|* PCE2, Philippe Conde
|* add menu option and support dbl click on purchased item(=leaf)
|
|* PCE 3 Philippe Conde, 2004-10-07, B40O_c4_expl
|* add dll for function done for leaf
|
|* PCE 4 Philippe Conde, 2004-11-16, B40O_c4_expl
|* change dll for function add parameter type from screen
|
|******************************************************************************
|* Main table tipcs022 Nomenclatures spécifiques, Form Type 4
|******************************************************************************
|* License	:
|* Copyright 2001 by <Philippe Conde>
|* 
|* All Rights Reserved 
|* 
|* Permission to use, copy, modify, and distribute this software and its
|* documentation for any purpose and without fee is hereby granted,
|* provided that the above copyright notice appear in all copies and that
|* both that copyright notice and this permission notice appear in
|* supporting documentation. 
|* 
|* Philippe Conde and Baanboard.com DISCLAIM ALL WARRANTIES WITH REGARD TO THIS
|* SOFTWARE, INCLUDING ALL IMPLIED WARRANTIES OF MERCHANTABILITY
|* AND FITNESS, IN NO EVENT SHALL Philippe conde nor Baanboard.com BE LIABLE FOR ANY
|* SPECIAL, INDIRECT OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES 
|* WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, 
|* WHETHER IN AN ACTION OF CONTRACT, NEGLIGENCE OR OTHER 
|* TORTIOUS ACTION, ARISING OUT OF OR IN CONNECTION WITH THE USE
|* OR PERFORMANCE OF THIS SOFTWARE.
|*                                                                               
|****************************** declaration section ***************************
declaration:
#ident "PCE3, Philippe Conde, 2004-10-07, B40O_c4_expl"

	table	ttipcs022	|* Nomenclatures spécifiques
	table	ttcmcs003	|* Magasins
	table	ttibom010	|* Nomenclatures de fabrication
	table	ttiitm001	|* Articles
	table	ttipcs021	|* Articles spécifiques
	table  	tttgfd400


		long		rc
	extern	domain	tcyesno       	txta.yn
		domain	tcmcs.str40	gbf_key
		domain	tcmcs.str80	gbf_desc
		domain	tcmcs.str40	head_key
		domain	tcdate		mydate
	extern	domain	tccprj        	cprj.f	fixed
	extern	domain	tcitem        	mitm.f	fixed
	extern	domain	tcdsca		dsca.f	fixed
	extern  domain	tcmcs.long	type.help
		long		int.iconset1
		long		int.iconset2
		long		leaf.iconset1
		long		leaf.iconset2
		long		hwnd.func
		long		menu.id
	extern	domain	tccprj		zoom.cprj
	extern	domain	tcitem		zoom.item
		
	#include "itggbfdefs" 	|* 
	#include "itgcomlogging" 	|* 
		
		
|****************************** form section **********************************

form.1:
init.form:
	mydate = date.num()
	get.screen.defaults()

|****************************** choice section ********************************

choice.cont.process:
on.choice:
	read.main.table()


|****************************** field section *********************************
field.mitm.f:
check.input:
	dsca.f = ""
	if isspace(cprj.f) then
		select tiitm001.* from tiitm001
		where tiitm001._index1 = {:mitm.f}
		as set with 1 rows
		selectdo		
		   if tiitm001.kitm <> tckitm.manufacture then
		   	set.input.error("spbom07191")
		   	|* Article non fabriqué
		   else
		   	dsca.f = tiitm001.dsca
		   endif
		selectempty
			set.input.error("spbom07192")
			|* Article inconnu
		endselect
	else
		select tipcs021.* from tipcs021
		where tipcs021._index1={:cprj.f, :mitm.f}
		as set with 1 rows
		selectdo		
		   if tipcs021.kitm <> tcpuma.manufacture then
		   	set.input.error("spbom07191")
		   	|* Article non fabriqué
		   else
		   	dsca.f = tipcs021.dsca
		   endif
		selectempty
			set.input.error("spbom07192")
			|* Article inconnu
		endselect
	endif	
	display(dsca.f)			

before.zoom:
	if isspace(cprj.f) then
		attr.zoomsession$ ="tiitm0502s000"
		attr.zoomreturn$ = "tiitm001.item"
		zoom.item = mitm.f
	else
		attr.zoomsession$ = "tipcs2522s000"
		attr.zoomreturn$ = "tipcs021.item"
		tipcs021.cprj = cprj.f
		zoom.cprj = cprj.f
	endif
	
|****************************** function section ******************************

functions:

function read.main.table()
{
	rc = init_data_gbf()
	
}


function long read.pcs022( domain tccprj mycprj, domain tcitem myitem )
{
	select	tipcs022.* from	tipcs022
	where   tipcs022._index1 = {:mycprj, :myitem}
	order by tipcs022._index1
	selectdo
		gbf_key(1;3) = edit$(tipcs022.pono,"999")
		gbf_key(10;16) = tipcs022.sitm(1;16)
		gbf_key(4;6) = "      "
		gbf_desc(1;3)=edit$(tipcs022.pono,"999")
		gbf_desc(4;1) = " "
		gbf_desc(5;6)="      "
		gbf_desc(11;2) = "  "
		gbf_desc(13;16)=tipcs022.sitm(1;16)
		gbf_desc(29;2)="  "
		gbf_desc(31;10) = edit$(tipcs022.qana, "ZZZZ9.VD999")
		gbf_desc(41;4)="   #"
		if tipcs022.opol = tcittb.customized then
			gbf_desc(5;6) = tipcs022.cprj(1;6)
			gbf_key(4;6) = tipcs022.cprj(1;6)
			select tipcs021.* from tipcs021
			where tipcs021._index1 = {:mycprj, :tipcs022.sitm}
			as set with 1 rows
			selectdo
				gbf_desc(45;30)=tipcs021.dsca(1;30)
				if tipcs021.kitm = tcpuma.manufacture then
					rc = gbf.add.interior(gbf_key, gbf_desc, 1)  |node
				else
|PCE2.o					rc = gbf.add.object(gbf_key, gbf_desc, 2, true, leaf.iconset2) |leaf
					rc = gbf.add.object(gbf_key, gbf_desc, 2,
					        true, leaf.iconset2, hwnd.func) |leaf
				endif
			endselect	
	        else
	        	select tiitm001.* from tiitm001
	        	where tiitm001._index1= {:tipcs022.sitm}
	        	as set with 1 rows
	        	selectdo
	        		gbf_desc(45;30) = tiitm001.dsca(1;30)
	        		if tiitm001.kitm = tckitm.manufacture then
					rc = gbf.add.object(gbf_key, gbf_desc, 1,
					            false, int.iconset2) | node
	        		else
|#PCE2.o				rc = gbf.add.object(gbf_key, gbf_desc, 2, true, leaf.iconset1) |leaf
 					rc = gbf.add.object(gbf_key, gbf_desc, 2, 
 						true, leaf.iconset1, hwnd.func) |#PCE2.n
				endif
			endselect
	        endif
	endselect
	return(0)
}
function long read.bom010(domain tcitem myitem)
{
	select	tibom010.*
	from	tibom010
	where   tibom010._index1 inrange {:myitem, 0}
	                             and {:myitem, 999}
	and (tibom010.exdt = 0 or
	     tibom010.exdt > :mydate ) 
	order by tibom010._index1
	selectdo
		gbf_key(1;3) = edit$(tibom010.pono,"999")
		gbf_key(4;6) = "      "
		gbf_key(10;16) = tibom010.sitm(1;16)
		gbf_desc(1;3)=edit$(tibom010.pono,"999")
		gbf_desc(4;1) = " "
		gbf_desc(5;6)="      "
		gbf_desc(11;2) = "  "
		gbf_desc(13;16)=tibom010.sitm(1;16)
		gbf_desc(29;2)="  "
		gbf_desc(31;10) = edit$(tibom010.qana, "ZZZZ9.VD999")
		gbf_desc(41;4)="   #"
	        select tiitm001.* from tiitm001
	        where tiitm001._index1 = {:tibom010.sitm}
	        as set with 1 rows
	    	selectdo
	        	gbf_desc(45;30) = tiitm001.dsca(1;30)
	    		if tiitm001.kitm = tckitm.manufacture then
				rc = gbf.add.object(gbf_key, gbf_desc, 1,
				          false, int.iconset2) |node
	    		else
|#PCE2.o			rc = gbf.add.object(gbf_key, gbf_desc, 2, true, leaf.iconset1) |leaf
 				rc = gbf.add.object(gbf_key, gbf_desc, 2, 
 				         true, leaf.iconset1, hwnd.func) |#PCE2.n
	    		endif
	        endselect
	endselect
	return(0)
}
function extern long init_data_gbf()
{

	long font.def(10), mwin1
	long	def.options
	long	ret_start
	long	retval

	head_key(1;10) =form.text$("spbom07196")
	|* Article
	head_key(10;6) = cprj.f(1;6)
	head_key(20;16) = mitm.f(1;16)
	
	def.options = GBF.OPT.DEFAULT   + GBF.OPT.DEBUG |+ GBF.OPT.UNSELECT

|	retval = gbf.init(gbf.current.library(), head_key,
|			bit.or(GBF.MENU.ALL  , GBF.MENU.FILE.OPEN),
|			bit.or(GBF.BUTTON.ALL, GBF.BUTTON.FILE.QUIT),
|			def.options)
	retval = gbf.init(gbf.current.library(), head_key,
			  GBF.MENU.ALL, GBF.BUTTON.ALL, def.options)
	LogExecErrorReturn(retval, "gbf.init()")

	int.iconset1 = gbf.set.interior.icon( "bom",
				"specm.normal",		|unselected.closed
				"specm.open",		|unselected.open
				"specm.closed",		|selected.closed
				"specm.open",		|selected.open
				true )			|Défault
	int.iconset2 = gbf.set.interior.icon( "bom",
				"standm.normal",	|unselected.closed
				"standm.normal",	|unselected.open
				"standm.select",	|selected.closed
				"standm.select",	|selected.open
				false )
	leaf.iconset1 = gbf.set.leaf.icon( "bom",
			 "purs.normal",
			 "purs.select",
			 TRUE)
	leaf.iconset2 = gbf.set.leaf.icon( "bom",
			 "pursp.normal",
			 "pursp.select",
			 false)
	
|	rc = gbf.get.resource(DsNfontset, dummy )
	mwin1 = current.mwindow()

|	obj_id = create.object(DsCfontSet, mwin1, font.def)
	
|	rc = gbf.set.resource(DsNfontset, dummy )
	
	retval = gbf.set.key.desc.length(40, 80)
	LogExecErrorReturn(retval, "gbf.set.key.desc.length(%d, %d)",
				40, 80)

	retval =  gbf.set.sort.strategy(  GBF.SORT.DESC
					+ GBF.SORT.ASCENDING
					+ GBF.SORT.INSENSITIVE)
	LogExecError(retval, "gbf.set.sort.strategy()")

	retval =  gbf.set.open.strategy(  GBF.OPEN.AGAIN
					+ GBF.OPEN.CURSEL
					+ GBF.OPEN.READALL)
	LogExecError(retval, "gbf.set.open.strategy()")
|#PCE2.sn 	1. Create menu
|		2. add function linked to menu
|		3. add item menu linked to menu and to fucntion
	menu.id = gbf.set.menu.head(form.text$("spbom07194"), 0,0)
	|* Nomenclature
	hwnd.func = gbf.set.menu.function(gbf.current.library(), "myfunc.leaf", TRUE )  | only for leaf
	rc = gbf.set.menu.item( menu.id, form.text$("spbom07195"),"",true, hwnd.func, 0 ,0)
	|* Detail stock & Prix
|#PCE2.en	
	
	ret_start = gbf.start(1, 1) 

	return (0)
}


function long find.bom(const string key.c())
{
	long	retval
	domain	tcitem	item.c
	domain	tccprj	cprj.c

	cprj.c = key.c(4;6)
	item.c = key.c(10;16)
	
	if isspace(cprj.c) then
		retval = read.bom010(item.c)
	else
		retval = read.pcs022(cprj.c,item.c)
	endif
	
	return (0)
}

|************************************************************************
|* call back function : is called in tggbfsrvlib
|************************************************************************
function extern long gbf.get.top.level()
{
	head_key(1;3) = "   "
	head_key(4;6) = cprj.f(1;6)
	head_key(10;16) = mitm.f(1;16)
	return (find.bom(head_key))
}

|************************************************************************
|* call back function : is called in tggbfsrvlib
|************************************************************************
function extern long gbf.get.children(const string key(),
					long value,
					long level)
{
	return (find.bom(key))
}

|************************************************************************
|* call back function : is called in tggbfsrvlib
|************************************************************************
function extern long gbf.save(
	const	long	object.id,
	const	string	object.key(),
	const	long	object.value,
	const	long	menu.value)
{
| Doesn't need save already in tables :-)
	return (0)
}

|#PCE2.sn
|************************************************************************
|* call back function : would be  called in tggbfsrvlib (Not working)
|************************************************************************
function extern long 	gbf.menu.selected(
	const	long	object.id,
	const	string	object.key(),
	const	long	object.value,
	const	long	menu.value)
{
	rc = gbf.set.label1("BOM")
	return (0)
}

|************************************************************************
|* call back function : is called in tggbfsrvlib
|* back here if a) line selected and 
|*              b) help on this item  
|************************************************************************
function extern long 	gbf.help.selected(
	const	long	object.id,
	const	string	object.key(),
	const	long	object.value,
	const	long	help.type)
{
	domain	tcitem 	item.l		|#PCE3.n
	domain	tccprj	cprj.l		|#PCE3.n
	
	if not isspace(object.key) then
		|#PCE3.sn
		cprj.l = object.key(4;6)
		item.l = object.key(10;16)
		message(spbom.dll0719.item.mess(cprj.l, item.l,type.help))
		|#PCE3.en
	endif
	return (0)
}

|#PCE3.so
|function string spbom0719.item.mess(const string key.l())
|{
|	if isspace(cprj.l) then
|		select tiitm001.* from tiitm001
|		where tiitm001._index1 = {:item.l}
|		as set with 1 rows
|		selectdo
|			if tiitm001.kitm = tckitm.manufacture then
|				return( sprintf$(form.text$("spbom07193"),
|				|* Stock = %d \n Prix = %d \n Poids = %d
|				tiitm001.stoc, tiitm001.copr, tiitm001.wght))
|			else
|				return( sprintf$(form.text$("spbom07193"),
|				|* Stock = %d \n Prix = %d \n Poids = %d
|-				tiitm001.stoc, tiitm001.avpr, tiitm001.wght))
|			endif
|		endselect
|	else
|		select tipcs021.* from tipcs021
|		where tipcs021._index1 = {:cprj.l, :item.l}
|		as set with 1 rows
|		selectdo
|-			return( sprintf$(form.text$("spbom07193"),
|			|* Stock = %d \n Prix = %d \n Poids = %d
|				tipcs021.stoc, tipcs021.cpra, tipcs021.wght))
|		endselect
|	endif
|	return("No message")
|}
|#PCE3.eo

function extern long myfunc.leaf(const long obj.id,
			    const string obj.key(),
			    const long obj.value,
			    const long obj.menu)
{
	domain	tcitem 	item.l		|#PCE3.n
	domain	tccprj	cprj.l		|#PCE3.n
	
	if not isspace(obj.key) then
		|#PCE3.sn
		cprj.l = obj.key(4;6)
		item.l = obj.key(10;16)
		message(spbom.dll0719.item.mess(cprj.l, item.l,type.help))
		|#PCE3.en
|#PCE3.o	message(spbom0719.item.mess(obj.key))
	endif
	return(0)
}
|#PCE2.en
Reply With Quote
  #35  
Old 29th May 2008, 11:58
moianix's Avatar
moianix moianix is offline
Junior Member
 
Join Date: Apr 2005
Posts: 19
moianix is on a distinguished road
Baan: IV c4 - DB: Oracle - OS: Aix - Win 2003
Hi Philippe or Bonjour Philippe

thx for your quick reply ...

i solved in another way ... surely is not the best ... but it run

Now i have another problem ... how can i refresh GBF screen when i cange something on BOM data ? see the markup "Question"

Thx for your help.
Best regards from Italy


function extern long init_data_gbf()
{
long def.options
long ret_start

head_key(1;16) = mitm.f(1;16)
retval = gbf.init(gbf.current.library(), head_key,
bit.or(GBF.MENU.ALL , GBF.MENU.FILE.OPEN),
bit.or(GBF.BUTTON.ALL, GBF.BUTTON.FILE.QUIT),
def.options)
LogExecErrorReturn(retval, "gbf.init()")

int.iconset1 = gbf.set.interior.icon( "bom",
"specm.normal", |unselected.closed
"specm.open", |unselected.open
"specm.closed", |selected.closed
"specm.open", |selected.open
true ) |Défault

int.iconset2 = gbf.set.interior.icon( "bom",
"standm.normal", |unselected.closed
"standm.normal", |unselected.open
"standm.select", |selected.closed
"standm.select", |selected.open
false )

int.iconset3 = gbf.set.interior.icon( "bom",
"ghost.normal", |unselected.closed
"ghost.normal", |unselected.open
"ghost.select", |selected.closed
"ghost.select", |selected.open
false )

leaf.iconset1 = gbf.set.leaf.icon( "bom",
"purs.normal",
"purs.select",
TRUE)
leaf.iconset2 = gbf.set.leaf.icon( "bom",
"pursp.normal",
"pursp.select",
false)

retval = gbf.set.key.desc.length(60, 60)
LogExecErrorReturn(retval, "gbf.set.key.desc.length(%d, %d)",60, 60)
retval = gbf.set.sort.strategy( GBF.SORT.DESC
+ GBF.SORT.ASCENDING
+ GBF.SORT.INSENSITIVE)
LogExecError(retval, "gbf.set.sort.strategy()")

retval = gbf.set.open.strategy( GBF.OPEN.AGAIN
+ GBF.OPEN.CURSEL
+ GBF.OPEN.READALL)
LogExecError(retval, "gbf.set.open.strategy()")

|--- Custom menu
|-- Title
menu.text = "Action"
menu.id = gbf.set.menu.head(menu.text,0,GBF.ZERO.DISABLE)
LogExecError(menu.id, "gbf.set.menu.head()")
|-- Menu selection
menu.text = "Maintain Item Data"
keystroke = ""
set.menu.item()
menu.text = "Maintain BOM Data"
keystroke = ""
set.menu.item()
|*******
ret_start = gbf.start(1, 1)

return (0)
}

function set.menu.item()
{
retval = gbf.set.menu.item(menu.id,menu.text,keystroke,0,menu.function.id,0,GBF.ZERO.DISABLE)
LogExecError(retval, "gbf.set.menu.item()")
}

|--- Action selected
function extern long gbf.menu.selected( long obj.id,
const string object.key(),
long object.value,
long menu.option)
{
|--- Value of menu.option
| 41 = "Maintain Item Data"
| 42 = "Maintain BOM Data"

ON CASE menu.option
CASE 41:
zoom.item = object.key(4;16)
export("zoom.item",zoom.item)
zoom.to$("tppdm0110s000",z.session,prog.name$,"",0)
break
CASE 42:
zoom.item = object.key(4;16)
export("zoom.item",zoom.item)
zoom.to$("tibom1110s000",z.session,prog.name$,"",0)
|***Question
|How to refresh data ????? init_data_gbf()
break

DEFAULT:
message("Invalid selection")
ENDCASE
return (0)
}
Reply With Quote
  #36  
Old 29th May 2008, 13:46
pconde pconde is offline
Senior Member
 
Join Date: May 2002
Location: Belgium
Posts: 162
pconde is on a distinguished road
Baan: BaanIVc4, BaanERP 5.0, ERP LN6.1 - DB: Oracle, informix, DB400 - OS: unix, As400, windows 2003
Hello,

I think that this is not so easy because the GBF tree is in memory and it is not refreshed.
It is the same problem as when you change a menu in the browser. If the menu was displayed in your browser before the change you can only see the change after exit bw and reload it.
So I have 2 ideas
a) redo a gbf.init and reload all.
b) use function gbf.delete.object + gbf.add.object
not sure that this should do the trick.

Regards
Philippe
Reply With Quote
Sponsored Links
  #37  
Old 29th May 2008, 14:23
moianix's Avatar
moianix moianix is offline
Junior Member
 
Join Date: Apr 2005
Posts: 19
moianix is on a distinguished road
Baan: IV c4 - DB: Oracle - OS: Aix - Win 2003
Hello

i go to try your ideas.

Thx.
Reply With Quote
  #38  
Old 6th March 2010, 21:00
ctarton1 ctarton1 is offline
Junior Member
 
Join Date: May 2005
Posts: 10
ctarton1 is on a distinguished road
Baan: Baan IVc4 - DB: Oracle - OS: Windows
Quote:
Originally Posted by moianix View Post
Hi Philippe or Bonjour Philippe

thx for your quick reply ...

i solved in another way ... surely is not the best ... but it run

Now i have another problem ... how can i refresh GBF screen when i cange something on BOM data ? see the markup "Question"

Thx for your help.
Best regards from Italy


function extern long init_data_gbf()
{
long def.options
long ret_start

head_key(1;16) = mitm.f(1;16)
retval = gbf.init(gbf.current.library(), head_key,
bit.or(GBF.MENU.ALL , GBF.MENU.FILE.OPEN),
bit.or(GBF.BUTTON.ALL, GBF.BUTTON.FILE.QUIT),
def.options)
LogExecErrorReturn(retval, "gbf.init()")

int.iconset1 = gbf.set.interior.icon( "bom",
"specm.normal", |unselected.closed
"specm.open", |unselected.open
"specm.closed", |selected.closed
"specm.open", |selected.open
true ) |Défault

int.iconset2 = gbf.set.interior.icon( "bom",
"standm.normal", |unselected.closed
"standm.normal", |unselected.open
"standm.select", |selected.closed
"standm.select", |selected.open
false )

int.iconset3 = gbf.set.interior.icon( "bom",
"ghost.normal", |unselected.closed
"ghost.normal", |unselected.open
"ghost.select", |selected.closed
"ghost.select", |selected.open
false )

leaf.iconset1 = gbf.set.leaf.icon( "bom",
"purs.normal",
"purs.select",
TRUE)
leaf.iconset2 = gbf.set.leaf.icon( "bom",
"pursp.normal",
"pursp.select",
false)

retval = gbf.set.key.desc.length(60, 60)
LogExecErrorReturn(retval, "gbf.set.key.desc.length(%d, %d)",60, 60)
retval = gbf.set.sort.strategy( GBF.SORT.DESC
+ GBF.SORT.ASCENDING
+ GBF.SORT.INSENSITIVE)
LogExecError(retval, "gbf.set.sort.strategy()")

retval = gbf.set.open.strategy( GBF.OPEN.AGAIN
+ GBF.OPEN.CURSEL
+ GBF.OPEN.READALL)
LogExecError(retval, "gbf.set.open.strategy()")

|--- Custom menu
|-- Title
menu.text = "Action"
menu.id = gbf.set.menu.head(menu.text,0,GBF.ZERO.DISABLE)
LogExecError(menu.id, "gbf.set.menu.head()")
|-- Menu selection
menu.text = "Maintain Item Data"
keystroke = ""
set.menu.item()
menu.text = "Maintain BOM Data"
keystroke = ""
set.menu.item()
|*******
ret_start = gbf.start(1, 1)

return (0)
}

function set.menu.item()
{
retval = gbf.set.menu.item(menu.id,menu.text,keystroke,0,menu.function.id,0,GBF.ZERO.DISABLE)
LogExecError(retval, "gbf.set.menu.item()")
}

|--- Action selected
function extern long gbf.menu.selected( long obj.id,
const string object.key(),
long object.value,
long menu.option)
{
|--- Value of menu.option
| 41 = "Maintain Item Data"
| 42 = "Maintain BOM Data"

ON CASE menu.option
CASE 41:
zoom.item = object.key(4;16)
export("zoom.item",zoom.item)
zoom.to$("tppdm0110s000",z.session,prog.name$,"",0)
break
CASE 42:
zoom.item = object.key(4;16)
export("zoom.item",zoom.item)
zoom.to$("tibom1110s000",z.session,prog.name$,"",0)
|***Question
|How to refresh data ????? init_data_gbf()
break

DEFAULT:
message("Invalid selection")
ENDCASE
return (0)
}
Hello,

for refresh data in the tree try to use this function:

function refresh.F5()
{
long event_2(EVTMAXSIZE)

evt.type(event_2) = EVTKEYPRESS
evt.keypress.key(event_2) = FKEY(5)
send.event(get.pgrp(PID), event_2)
}
Reply With Quote
Reply


Currently Active Users Viewing This Thread: 1 (0 members and 1 guests)
 
Thread Tools
Display Modes

Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

vB code is On
Smilies are Off
[IMG] code is Off
HTML code is Off
Forum Jump

Similar Threads
Thread Thread Starter Forum Replies Last Post
Baanboard code to display Images Belitre Tools Development 3 17th May 2004 16:19
CODE: Starting Baan browser from VB steveauckly Code & Utilities 4 27th September 2003 08:48
HP Unix help plse pjohns Operating Systems & Databases 3 16th May 2003 15:10
NEW: vbcode CODE extensions patvdv About Baanboard.com 3 13th March 2003 11:19
How to print from within BaanERP 5.0c display browser ? dbclark79 Tools Development 0 16th July 2002 15:43


All times are GMT +2. The time now is 12:11.


©2001-2017 - Baanboard.com - Baanforums.com